gentoo-ebuilds/dev-build/slibtool/slibtool-0.7.0.ebuild
Sam James 6a7638f9f9
dev-build/slibtool: use foss21.org
Same place but semantically better to use foss21 for non-directly-midipix bits.

Signed-off-by: Sam James <sam@gentoo.org>
2025-05-17 14:21:46 +01:00

41 lines
1.1 KiB
Bash

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
# git.foss21.org is the official repository per upstream
DESCRIPTION="A strong libtool implementation, written in C"
HOMEPAGE="https://git.foss21.org/slibtool"
if [[ "${PV}" == *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://git.foss21.org/slibtool"
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/midipix.asc
inherit verify-sig
SRC_URI="https://dl.foss21.org/slibtool/${P}.tar.xz"
SRC_URI+=" verify-sig? ( https://dl.foss21.org/slibtool/${P}.tar.xz.sig )"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
fi
BDEPEND="sys-devel/m4"
if [[ ${PV} != *9999 ]] ; then
BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-midipix-20250517 )"
fi
LICENSE="MIT"
SLOT="0"
src_configure() {
# Custom configure script (not generated by autoconf)
./configure \
--compiler="$(tc-getCC)" \
--host=${CHOST} \
--prefix="${EPREFIX}"/usr \
--libdir="${EPREFIX}/usr/$(get_libdir)" \
|| die
}