mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-07-21 14:38:43 +02:00
051a757949
20220623 is needed for bear-3.1.2 and without this patch, bear cannot be installed on musl profiles. Bug: https://bugs.gentoo.org/906218 Signed-off-by: Brahmajit Das <brahmajit.xyz@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/32095 Signed-off-by: Sam James <sam@gentoo.org>
70 lines
1.7 KiB
Bash
70 lines
1.7 KiB
Bash
# Copyright 2020-2023 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{9..11} )
|
|
|
|
inherit cmake python-any-r1
|
|
|
|
# yes, it needs SOURCE, not just installed one
|
|
# and no, 1.11.0 is not enough
|
|
GTEST_COMMIT="e68764c147ea0dac1e8811925c531d937396878e"
|
|
GTEST_FILE="gtest-${GTEST_COMMIT}.tar.gz"
|
|
|
|
DESCRIPTION="Abseil Common Libraries (C++), LTS Branch"
|
|
HOMEPAGE="https://abseil.io"
|
|
SRC_URI="https://github.com/abseil/abseil-cpp/archive/${PV}.tar.gz -> ${P}.tar.gz
|
|
test? ( https://github.com/google/googletest/archive/${GTEST_COMMIT}.tar.gz -> ${GTEST_FILE} )"
|
|
|
|
LICENSE="
|
|
Apache-2.0
|
|
test? ( BSD )
|
|
"
|
|
SLOT="0/${PV%%.*}"
|
|
KEYWORDS="amd64 ~arm arm64 ~loong ppc64 ~riscv x86"
|
|
IUSE="test"
|
|
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
test? ( sys-libs/timezone-data )
|
|
"
|
|
|
|
RESTRICT="!test? ( test )"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${PN}-20230125.2-musl-1.2.4.patch #906218
|
|
)
|
|
|
|
src_prepare() {
|
|
cmake_src_prepare
|
|
|
|
# un-hardcode abseil compiler flags
|
|
sed -i \
|
|
-e '/"-maes",/d' \
|
|
-e '/"-msse4.1",/d' \
|
|
-e '/"-mfpu=neon"/d' \
|
|
-e '/"-march=armv8-a+crypto"/d' \
|
|
absl/copts/copts.py || die
|
|
|
|
# now generate cmake files
|
|
python_fix_shebang absl/copts/generate_copts.py
|
|
absl/copts/generate_copts.py || die
|
|
|
|
if use test; then
|
|
sed -i 's/-Werror//g' \
|
|
"${WORKDIR}/googletest-${GTEST_COMMIT}"/googletest/cmake/internal_utils.cmake || die
|
|
fi
|
|
}
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DCMAKE_CXX_STANDARD=17
|
|
-DABSL_ENABLE_INSTALL=TRUE
|
|
-DABSL_LOCAL_GOOGLETEST_DIR="${WORKDIR}/googletest-${GTEST_COMMIT}"
|
|
-DABSL_PROPAGATE_CXX_STD=TRUE
|
|
-DABSL_BUILD_TESTING=$(usex test ON OFF)
|
|
$(usex test -DBUILD_TESTING=ON '') #intentional usex, it used both variables for tests.
|
|
)
|
|
cmake_src_configure
|
|
}
|