mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-07-21 14:38:43 +02:00
b8cca5206e
Closes: https://bugs.gentoo.org/945375 Signed-off-by: Denis Pronin <dannftk@yandex.ru> Closes: https://github.com/gentoo/gentoo/pull/39525 Signed-off-by: Sam James <sam@gentoo.org>
54 lines
1.3 KiB
Bash
54 lines
1.3 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{10..13} )
|
|
inherit gnome.org meson-multilib python-any-r1
|
|
|
|
DESCRIPTION="C++ interface for glib2"
|
|
HOMEPAGE="https://www.gtkmm.org https://gitlab.gnome.org/GNOME/glibmm"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="2.68"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
|
|
IUSE="gtk-doc debug test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.77.0:2[${MULTILIB_USEDEP}]
|
|
dev-libs/libsigc++:3[gtk-doc?,${MULTILIB_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
virtual/pkgconfig
|
|
gtk-doc? (
|
|
app-text/doxygen[dot]
|
|
dev-lang/perl
|
|
dev-libs/libxslt
|
|
)
|
|
"
|
|
|
|
PATCHES=( "${FILESDIR}"/${P}-libcxx-fix.patch )
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
|
|
sed -i -e '/giomm_tls_client/d' tests/meson.build || die
|
|
|
|
if ! use test; then
|
|
sed -i -e "/^subdir('tests')/d" meson.build || die
|
|
fi
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
-Dwarnings=min
|
|
-Dbuild-deprecated-api=true
|
|
$(meson_native_use_bool gtk-doc build-documentation)
|
|
$(meson_use debug debug-refcounting)
|
|
-Dbuild-examples=false
|
|
)
|
|
meson_src_configure
|
|
}
|