gentoo-ebuilds/dev-java/commons-cli/commons-cli-1.9.0-r1.ebuild
Volkmar W. Pogatzki e698666519
dev-java/commons-cli: avoid circular dependency with java-dep-check
This commit adds JAVA_DISABLE_DEPEND_ON_JAVA_DEP_CHECK="true" in order
to avoid a circular dependency with dev-java/java-dep-check which is now
forced into BDEPEND.

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Part-of: https://github.com/gentoo/gentoo/pull/42182
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
2025-07-10 09:51:00 +02:00

44 lines
1.3 KiB
Bash

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# No tests, #839681
JAVA_PKG_IUSE="doc source"
MAVEN_ID="commons-cli:commons-cli:1.9.0"
# Avoid circular dependency
JAVA_DISABLE_DEPEND_ON_JAVA_DEP_CHECK="true"
inherit java-pkg-2 java-pkg-simple verify-sig
DESCRIPTION="A Java library for working with the command line arguments and options"
HOMEPAGE="https://commons.apache.org/proper/commons-cli/"
SRC_URI="mirror://apache/commons/cli/source/${P}-src.tar.gz
verify-sig? ( https://downloads.apache.org/commons/cli/source/${P}-src.tar.gz.asc )"
S="${WORKDIR}/${P}-src"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm64 ppc64 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/commons.apache.org.asc"
BDEPEND="verify-sig? ( sec-keys/openpgp-keys-apache-commons )"
DEPEND=">=virtual/jdk-11:*" # module-info
RDEPEND=">=virtual/jre-1.8:*"
JAVA_SRC_DIR="src/main/java"
src_compile() {
JAVA_JAR_FILENAME="org.apache.${PN}.jar"
java-pkg-simple_src_compile # creates a legacy jar file without module-info
jdeps --generate-module-info \
src/main/java \
--multi-release 9 \
"${JAVA_JAR_FILENAME}" || die
JAVA_JAR_FILENAME="${PN}.jar"
java-pkg-simple_src_compile # creates the final jar file including module-info
}