mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-13 21:47:44 +00:00
d83e25b6a5sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
51 lines
1.2 KiB
Bash
51 lines
1.2 KiB
Bash
# Copyright 2015-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=7
|
|
|
|
inherit meson-multilib
|
|
|
|
DESCRIPTION="GObject bindings for libudev"
|
|
HOMEPAGE="https://wiki.gnome.org/Projects/libgudev"
|
|
SRC_URI="https://download.gnome.org/sources/libgudev/${PV}/${P}.tar.xz"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="0/0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
IUSE="introspection test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.38.0:2[${MULTILIB_USEDEP}]
|
|
>=virtual/libudev-251:=[sticky-tags(+),${MULTILIB_USEDEP}]
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
test? ( dev-util/umockdev[${MULTILIB_USEDEP}] )
|
|
"
|
|
BDEPEND="
|
|
dev-util/glib-utils
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${PV}-clang18-export-dynamic.patch #926350
|
|
)
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
$(meson_native_use_feature introspection)
|
|
-Dgtk_doc=false
|
|
$(meson_feature test tests)
|
|
-Dvapi=disabled
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
# libsandbox interferes somehow.
|
|
# There are no access violations, but tests fail.
|
|
# https://bugs.gentoo.org/805449
|
|
local -x SANDBOX_ON=0
|
|
meson-multilib_src_test
|
|
}
|