mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-13 21:47:44 +00:00
fd5269b1c8Nic: Package merged from oubliette-overlay https://github.com/nabbi/oubliette-overlay/tree/master/dev-libs/libjwt Jaco <jaco@uls.co.za> reached out regarding new Asterisk releases depending on libjwt Bill <dek.devel@baisenvar.info> originally supplied, along with the patch, for Zoneminder builds The three of us agreed to proxy-maintain until a more suitable owner is found. Hopefully this all makes sense, yet I suspect we missed something :D Jaco: Needs bump to 1.16.0 (configure patch doesn't apply). Didn't commit -9999 due to patch not applying, will bring back when I get 1.16.0 working. Signed-off-by: Jaco Kroon <jaco@uls.co.za> Signed-off-by: Nic Boet <nic@boet.cc> Closes: https://bugs.gentoo.org/915565 Closes: https://github.com/gentoo/gentoo/pull/35189 Signed-off-by: Sam James <sam@gentoo.org>
68 lines
1.3 KiB
Bash
68 lines
1.3 KiB
Bash
# Copyright 2022-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools
|
|
|
|
DESCRIPTION="JWT C Library"
|
|
HOMEPAGE="https://github.com/benmcollins/libjwt"
|
|
if [[ ${PV} == 9999 ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/benmcollins/libjwt"
|
|
else
|
|
SRC_URI="https://github.com/benmcollins/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
KEYWORDS="~amd64 ~x86"
|
|
fi
|
|
|
|
LICENSE="MPL-2.0"
|
|
SLOT="0"
|
|
# openssl / gnutls set which ssl implementations to use (build libjwt-ossl.so / libjwt-gnutls.so)
|
|
# IF openssl is enabled it will be the implementation used for libjwt.so
|
|
# gnutls will only be used for libjwt.so if openssl is disabled
|
|
IUSE="gnutls +openssl test"
|
|
|
|
REQUIRED_USE="
|
|
|| ( gnutls openssl )
|
|
"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-libs/jansson
|
|
gnutls? (
|
|
net-libs/gnutls:=
|
|
)
|
|
openssl? (
|
|
dev-libs/openssl:=
|
|
)
|
|
"
|
|
|
|
DEPEND="
|
|
${RDEPEND}
|
|
test? ( dev-libs/check )
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/libjwt-1.15.3_multi_ssl_atools.patch"
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
local myeconfargs=(
|
|
--enable-multi-ssl
|
|
$(use_with gnutls)
|
|
$(use_with openssl)
|
|
--with-default-ssl=$(usex openssl openssl gnutls)
|
|
)
|
|
|
|
econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
find "${ED}" -name '*.la' -delete || die
|
|
}
|