mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-08 06:09:43 +02:00
aa8ae319da
moto isn't used at all in this package, nor was it ever used. Searching git history for the word "moto" finds nothing. No mention of moto in github issues/pull requests/... It was added as fix for [1], but there was no "moto" in the build.log We can conclude it was added by mistake and was never needed. [1] https://bugs.gentoo.org/723554 Also-checked-by: Michał Górny <mgorny@gentoo.org> Also-checked-by: Sam James <sam@gentoo.org> Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
71 lines
1.7 KiB
Bash
71 lines
1.7 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{10..13} )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Google Authentication Library"
|
|
HOMEPAGE="
|
|
https://github.com/googleapis/google-auth-library-python/
|
|
https://pypi.org/project/google-auth/
|
|
"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm64 x86"
|
|
|
|
RDEPEND="
|
|
<dev-python/cachetools-6.0.0[${PYTHON_USEDEP}]
|
|
>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
|
|
>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
|
|
>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/aioresponses[${PYTHON_USEDEP}]
|
|
>=dev-python/cryptography-38.0.3[${PYTHON_USEDEP}]
|
|
dev-python/flask[${PYTHON_USEDEP}]
|
|
dev-python/freezegun[${PYTHON_USEDEP}]
|
|
dev-python/mock[${PYTHON_USEDEP}]
|
|
>=dev-python/pyjwt-2.0[${PYTHON_USEDEP}]
|
|
dev-python/pyopenssl[${PYTHON_USEDEP}]
|
|
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
|
|
dev-python/pytest-localserver[${PYTHON_USEDEP}]
|
|
dev-python/pyu2f[${PYTHON_USEDEP}]
|
|
dev-python/requests[${PYTHON_USEDEP}]
|
|
dev-python/responses[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
distutils-r1_src_prepare
|
|
|
|
# unpin deps
|
|
sed -i -e 's:,<[0-9.]*::' setup.py || die
|
|
}
|
|
|
|
python_compile() {
|
|
distutils-r1_python_compile
|
|
find "${BUILD_DIR}" -name '*.pth' -delete || die
|
|
}
|
|
|
|
python_test() {
|
|
local EPYTEST_DESELECT=(
|
|
# tests are broken with up-to-date pyopenssl
|
|
tests/transport/test__mtls_helper.py::TestDecryptPrivateKey::test_success
|
|
)
|
|
local EPYTEST_IGNORE=(
|
|
# these are compatibility tests with oauth2client
|
|
# disable them to unblock removal of that package
|
|
tests/test__oauth2client.py
|
|
)
|
|
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
epytest -p asyncio
|
|
}
|