mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-15 06:29:24 +00:00
befcec783bThere is a thread discussing porting with a patch, its unclear if it will be merged (and what the process is). https://sourceforge.net/p/extremetuxracer/discussion/help/thread/6de9a5beae/ Signed-off-by: Alfred Wingate <parona@protonmail.com> Part-of: https://github.com/gentoo/gentoo/pull/41992 Closes: https://github.com/gentoo/gentoo/pull/41992 Signed-off-by: James Le Cuirot <chewi@gentoo.org>
41 lines
1.1 KiB
Bash
41 lines
1.1 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools desktop xdg
|
|
|
|
DESCRIPTION="High speed arctic racing game based on Tux Racer"
|
|
HOMEPAGE="https://sourceforge.net/p/extremetuxracer/wiki/Home/"
|
|
SRC_URI="https://download.sourceforge.net/extremetuxracer/etr-${PV}.tar.xz -> ${P}.tar.xz"
|
|
S="${WORKDIR}/etr-${PV/_/}"
|
|
|
|
LICENSE="GPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
|
|
|
|
# <media-libs/libsfml-3: breaking changes
|
|
# https://sourceforge.net/p/extremetuxracer/discussion/help/thread/6de9a5beae/
|
|
RDEPEND="
|
|
<media-libs/libsfml-3.0
|
|
>=media-libs/libsfml-2.4:0=
|
|
virtual/glu
|
|
virtual/opengl
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="virtual/pkgconfig"
|
|
|
|
src_prepare() {
|
|
default
|
|
# kind of ugly in there so we'll do it ourselves
|
|
sed -i -e '/SUBDIRS/s/resources doc//' Makefile.am || die
|
|
eautoreconf
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
dodoc doc/{code,courses_events,guide,score_algorithm}
|
|
doicon -s 64 resources/etr.png
|
|
doicon -s scalable resources/etr.svg
|
|
domenu resources/net.sourceforge.extremetuxracer.desktop
|
|
}
|