mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-16 23:19:31 +00:00
f42710561cUpdate done using: ``` git grep -l sys-libs/zlib sys-* | xargs sed -i -e s@sys-libs/zlib@virtual/zlib@g git grep -l virtual/zlib-ng sys-* | xargs sed -i -e s@virtual/zlib-ng@sys-libs/zlib-ng@g git diff --name-only | xargs copybump git diff --name-only | xargs grep -l PYTHON_COMPAT | xargs gpy-impl -@dead pkgcheck scan --commits -c SourcingCheck,VisibilityCheck --exit error ``` Plus reverts in sys-libs/minizip-ng, sys-libs/zlib-ng and profiles. Signed-off-by: Michał Górny <mgorny@gentoo.org>
70 lines
1.3 KiB
Bash
70 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit cmake xdg-utils
|
|
|
|
DESCRIPTION="Open source reimplementation of Jazz Jackrabbit 2"
|
|
HOMEPAGE="
|
|
https://deat.tk/jazz2/
|
|
https://github.com/deathkiller/jazz2-native
|
|
"
|
|
SRC_URI="
|
|
https://github.com/deathkiller/jazz2-native/archive/refs/tags/${PV}.tar.gz
|
|
-> ${P}.tar.gz
|
|
"
|
|
S="${WORKDIR}/${PN}-native-${PV}"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
IUSE="+openal sdl"
|
|
|
|
DEPEND="
|
|
virtual/zlib:=
|
|
media-libs/libglvnd
|
|
openal? (
|
|
media-libs/libopenmpt
|
|
media-libs/openal
|
|
)
|
|
!sdl? ( media-libs/glfw )
|
|
sdl? ( media-libs/libsdl2 )
|
|
"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
src_prepare() {
|
|
# We need to install README.md to a different directory, default
|
|
# src_install will handle that.
|
|
sed -i '/README_INSTALL_DESTINATION/d' cmake/ncine_installation.cmake || die
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
local backend=GLFW
|
|
use sdl && backend=SDL2
|
|
local mycmakeargs=(
|
|
-DNCINE_LINUX_PACKAGE="${PN}"
|
|
|
|
-DNCINE_DOWNLOAD_DEPENDENCIES=OFF
|
|
-DNCINE_LINKTIME_OPTIMIZATION=OFF
|
|
-DNCINE_STRIP_BINARIES=OFF
|
|
-DNCINE_VERSION_FROM_GIT=OFF
|
|
-DNCINE_WITH_BACKWARD=OFF
|
|
|
|
-DNCINE_WITH_GLEW=OFF
|
|
|
|
-DNCINE_PREFERRED_BACKEND=${backend}
|
|
|
|
-DNCINE_WITH_AUDIO=$(usex openal)
|
|
)
|
|
cmake_src_configure
|
|
}
|
|
|
|
pkg_postinst() {
|
|
xdg_icon_cache_update
|
|
}
|
|
|
|
pkg_postrm() {
|
|
xdg_icon_cache_update
|
|
}
|