gentoo-ebuilds/gui-apps/gnome-console/gnome-console-46.0.ebuild
Arthur Zamarin 1feb03bdfd
gui-apps/gnome-console: Stabilize 46.0 arm64, #946484
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
2024-12-20 20:36:55 +00:00

53 lines
993 B
Bash

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org gnome2-utils meson xdg
DESCRIPTION="A simple user-friendly terminal emulator for the GNOME desktop"
HOMEPAGE="https://apps.gnome.org/Console/ https://gitlab.gnome.org/GNOME/console"
LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="amd64 arm64 ~loong"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.76:2
>=gui-libs/gtk-4.12.2:4
>=gui-libs/libadwaita-1.4_alpha:1
>=gui-libs/vte-0.75.1:2.91-gtk4
gnome-base/libgtop:2=
>=dev-libs/libpcre2-10.32:0=
gnome-base/gsettings-desktop-schemas
x11-libs/pango
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? (
dev-util/desktop-file-utils
dev-libs/appstream-glib
)
"
src_configure() {
local emesonargs=(
-Ddevel=false
$(meson_use test tests)
)
meson_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}