gentoo-ebuilds/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-25.04.3.ebuild
Andreas Sturmlechner 39c7ff4741
kde-apps/dolphin-plugins-dropbox: 25.04.3 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2025-07-05 20:06:00 +02:00

56 lines
1.2 KiB
Bash

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
KDE_ORG_NAME="dolphin-plugins"
MY_PLUGIN_NAME="dropbox"
PVCUT=$(ver_cut 1-3)
KFMIN=6.13.0
QTMIN=6.7.2
inherit ecm gear.kde.org
DESCRIPTION="Dolphin plugin for Dropbox service integration"
HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64"
IUSE=""
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[gui,network,widgets]
>=kde-apps/dolphin-${PVCUT}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
"
RDEPEND="${DEPEND}
>=kde-apps/dolphin-plugins-common-${PV}
net-misc/dropbox-cli
"
src_prepare() {
ecm_src_prepare
ecm_punt_po_install
# qtconcurrent only required by git
ecm_punt_qt_module Concurrent
# solid, qtdbus only required by mountiso
ecm_punt_qt_module DBus
ecm_punt_kf_module Solid
}
src_configure() {
local mycmakeargs=(
-DBUILD_${MY_PLUGIN_NAME}=ON
-DBUILD_bazaar=OFF
-DBUILD_git=OFF
-DBUILD_hg=OFF
-DBUILD_makefileactions=OFF
-DBUILD_mountiso=OFF
-DBUILD_svn=OFF
)
ecm_src_configure
}