gentoo-ebuilds/media-fonts/source-code-pro/source-code-pro-2.042-r1.ebuild
Alfred Wingate 470b68bb86
media-fonts/*: include missing font_pkg_postinst
Closes: https://bugs.gentoo.org/949601
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Sam James <sam@gentoo.org>
2025-02-11 14:26:18 +00:00

40 lines
1 KiB
Bash

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit font optfeature
REALV="2.042R-u/1.062R-i/1.026R-vf"
DESCRIPTION="Monospaced font family for user interface and coding environments"
HOMEPAGE="https://adobe-fonts.github.io/source-code-pro/"
SRC_URI="https://github.com/adobe-fonts/source-code-pro/archive/${REALV}.tar.gz -> source-code-pro-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${REALV//\//-}"
LICENSE="OFL-1.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~loong ppc ppc64 ~riscv sparc x86 ~x64-macos"
RESTRICT="binchecks strip"
RDEPEND="
media-libs/fontconfig
"
FONT_CONF=( "${FILESDIR}"/63-${PN}.conf )
FONT_SUFFIX="otf"
src_prepare() {
default
mv OTF/*.otf . || die
}
pkg_postinst() {
font_pkg_postinst
optfeature_header "Other variants of this font are:"
optfeature "Chinese, Japanese and Korean support" media-fonts/source-han-sans
optfeature "the sans-serif variant" media-fonts/source-sans
optfeature "the serif variant" media-fonts/source-serif
}