mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-15 06:29:24 +00:00
d83e25b6a5sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
55 lines
1.3 KiB
Bash
55 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{10..12} )
|
|
|
|
inherit meson python-r1
|
|
|
|
DESCRIPTION="SDK for making video editors and more"
|
|
HOMEPAGE="http://wiki.pitivi.org/wiki/GES"
|
|
SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P/gstreamer/gst}.tar.xz"
|
|
S="${WORKDIR}"/${P/gstreamer/gst}
|
|
|
|
LICENSE="LGPL-2+"
|
|
SLOT="1.0"
|
|
KEYWORDS="amd64 ~arm64 x86"
|
|
|
|
IUSE="+introspection test"
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
# Some tests are failing
|
|
RESTRICT="test"
|
|
|
|
RDEPEND="
|
|
${PYTHON_DEPS}
|
|
>=dev-libs/glib-2.40.0:2
|
|
dev-libs/libxml2:2=
|
|
>=media-libs/gstreamer-${PV}:1.0[introspection?]
|
|
>=media-libs/gst-plugins-base-${PV}:1.0[introspection?]
|
|
>=media-libs/gst-plugins-bad-${PV}:1.0[introspection?]
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="virtual/pkgconfig"
|
|
|
|
src_configure() {
|
|
python_setup
|
|
|
|
local emesonargs=(
|
|
-Ddoc=disabled # hotdoc not packaged
|
|
$(meson_feature introspection)
|
|
$(meson_feature test tests)
|
|
-Dbash-completion=disabled
|
|
-Dxptv=disabled
|
|
-Dpython=enabled
|
|
-Dvalidate=disabled
|
|
-Dexamples=disabled
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
python_moduleinto gi.overrides
|
|
python_foreach_impl python_domodule bindings/python/gi/overrides/GES.py
|
|
}
|