mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-08 06:09:43 +02:00
9b71b51386
Fix missing function parameters for C23. Add upstream patch that deleted non-existent symbol from linking script for Clang/LLD Closes: https://bugs.gentoo.org/925671 Closes: https://bugs.gentoo.org/944163 Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com> Closes: https://github.com/gentoo/gentoo/pull/41436 Signed-off-by: James Le Cuirot <chewi@gentoo.org>
71 lines
1.7 KiB
Bash
71 lines
1.7 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools multilib-minimal optfeature
|
|
|
|
MY_PN="${PN%-compat}"
|
|
MY_P="${MY_PN}-${PV}"
|
|
|
|
DESCRIPTION="Video Acceleration (VA) API for Linux"
|
|
HOMEPAGE="https://github.com/intel/libva"
|
|
SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
|
|
S="${WORKDIR}/${MY_P}"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="1"
|
|
KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
|
|
IUSE="+drm egl opengl wayland X"
|
|
|
|
RDEPEND=">=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
|
|
X? (
|
|
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
|
|
)
|
|
egl? ( >=media-libs/mesa-9.1.6[egl(+),${MULTILIB_USEDEP}] )
|
|
opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
|
|
wayland? ( >=dev-libs/wayland-1.0.6[${MULTILIB_USEDEP}] )
|
|
!media-libs/libva:0/0"
|
|
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="virtual/pkgconfig"
|
|
|
|
REQUIRED_USE="|| ( drm wayland X )
|
|
opengl? ( X )"
|
|
|
|
DOCS=( NEWS )
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}/${P}-missing-decl.patch"
|
|
"${FILESDIR}/${P}-nonexisting-symbol.patch"
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
eautoreconf
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local myeconfargs=(
|
|
--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
|
|
$(use_enable opengl glx)
|
|
$(use_enable X x11)
|
|
$(use_enable wayland)
|
|
$(use_enable egl)
|
|
$(use_enable drm)
|
|
)
|
|
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
multilib_src_install() {
|
|
emake -C va DESTDIR="${D}" install-libLTLIBRARIES
|
|
rm -vf "${ED}"/usr/$(get_libdir)/*.{la,so} || die
|
|
}
|
|
|
|
pkg_postinst() {
|
|
optfeature_header
|
|
optfeature "Older Intel GPU support" media-libs/libva-intel-driver
|
|
optfeature "Newer Intel GPU support" media-libs/libva-intel-media-driver
|
|
}
|