gentoo-ebuilds/media-libs/tse3/tse3-0.3.1-r2.ebuild
Lucio Sauer 794061a329
*/*: inline mirror://sourceforge
bump copyright of touched ebuilds to 2024

Signed-off-by: Lucio Sauer <watermanpaint@posteo.net>
Signed-off-by: Michał Górny <mgorny@gentoo.org>
2024-04-30 20:21:05 +02:00

55 lines
1.2 KiB
Bash

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools flag-o-matic
DESCRIPTION="TSE3 Sequencer library"
HOMEPAGE="https://TSE3.sourceforge.net"
SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.gz
mirror://gentoo/${P}-awe_voice.h.tbz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc sparc x86"
IUSE="alsa oss"
RDEPEND="alsa? ( media-libs/alsa-lib )"
DEPEND="${RDEPEND}"
PATCHES=(
"${FILESDIR}/${PN}-0.2.7-size_t-64bit.patch"
"${FILESDIR}/${PN}-0.2.7-gcc4.patch"
"${FILESDIR}/${P}-parallelmake.patch"
"${FILESDIR}/${P}+gcc-4.3.patch"
)
src_prepare() {
default
mv configure.in configure.ac || die "Moving configure.in -> .ac failed"
if use oss; then
cp "${WORKDIR}"/awe_voice.h src/ || die "copy failed"
append-cppflags -DHAVE_AWE_VOICE_H
fi
eautoreconf
}
src_configure() {
local myconf
use alsa || myconf="${myconf} --without-alsa"
use oss || myconf="${myconf} --without-oss"
econf \
--without-doc-install \
--without-aRts \
${myconf}
}
src_install() {
HTML_DOCS=( doc/*.{html,gif,png} )
default
find "${ED}" -type f -name '*.la' -delete || die
dodoc doc/History
}