mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-26 05:32:36 +00:00
1d6a5da916one change: remove the outdated HOMEPAGE Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr> Part-of: https://github.com/gentoo/gentoo/pull/45039 Closes: https://github.com/gentoo/gentoo/pull/45039 Signed-off-by: Sam James <sam@gentoo.org>
46 lines
1.2 KiB
Bash
46 lines
1.2 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
DISTUTILS_SINGLE_IMPL=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
inherit desktop distutils-r1 xdg
|
|
|
|
DESCRIPTION="Elegant GTK+ music client for the Music Player Daemon (MPD)"
|
|
HOMEPAGE="https://github.com/multani/sonata"
|
|
SRC_URI="https://github.com/multani/sonata/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~ppc ~x86"
|
|
IUSE="dbus taglib"
|
|
|
|
RDEPEND="
|
|
dev-libs/glib:2[introspection]
|
|
x11-libs/gdk-pixbuf:2[introspection]
|
|
x11-libs/gtk+:3[introspection]
|
|
x11-libs/pango[introspection]
|
|
$(python_gen_cond_dep '
|
|
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
|
dev-python/python-mpd2[${PYTHON_USEDEP}]
|
|
dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
|
|
taglib? ( dev-python/tagpy[${PYTHON_USEDEP}] )
|
|
')
|
|
"
|
|
BDEPEND="sys-devel/gettext"
|
|
|
|
distutils_enable_tests unittest
|
|
|
|
src_compile() {
|
|
distutils-r1_src_compile
|
|
# see bug #956771
|
|
find "${WORKDIR}" -name 'genversion.*' -delete || die
|
|
}
|
|
|
|
src_install() {
|
|
distutils-r1_src_install
|
|
doicon -s 128 sonata/pixmaps/sonata.png
|
|
rm -r "${ED}"/usr/share/sonata || die
|
|
}
|