mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-08 06:09:43 +02:00
f2905ea0c5
As with nghttp2 and nghttp3, there's a circular dependency with cmake->curl->ngtcp2, so let's avoid that by building ngtcp2 with autotools. Bug: https://bugs.gentoo.org/951524 Signed-off-by: Sam James <sam@gentoo.org>
60 lines
1.3 KiB
Bash
60 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
# Built with autotools rather than cmake to avoid circular dep (bug #951524
|
|
|
|
inherit multilib-minimal
|
|
|
|
if [[ ${PV} == 9999 ]] ; then
|
|
EGIT_REPO_URI="https://github.com/ngtcp2/ngtcp2.git"
|
|
inherit autotools git-r3
|
|
else
|
|
SRC_URI="https://github.com/ngtcp2/ngtcp2/releases/download/v${PV}/${P}.tar.xz"
|
|
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
|
|
fi
|
|
|
|
DESCRIPTION="Implementation of the IETF QUIC Protocol"
|
|
HOMEPAGE="https://github.com/ngtcp2/ngtcp2"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0/0"
|
|
IUSE="+gnutls openssl +ssl"
|
|
REQUIRED_USE="ssl? ( || ( gnutls openssl ) )"
|
|
|
|
RDEPEND="
|
|
ssl? (
|
|
gnutls? ( >=net-libs/gnutls-3.7.2:=[${MULTILIB_USEDEP}] )
|
|
openssl? ( >=dev-libs/openssl-1.1.1:=[${MULTILIB_USEDEP}] )
|
|
)
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="virtual/pkgconfig"
|
|
|
|
src_prepare() {
|
|
default
|
|
[[ ${PV} == 9999 ]] && eautoreconf
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local myeconfargs=(
|
|
--disable-werror
|
|
--enable-lib-only
|
|
$(use_with openssl)
|
|
$(use_with gnutls)
|
|
--without-boringssl
|
|
--without-picotls
|
|
--without-wolfssl
|
|
--without-libev
|
|
--without-libnghttp3
|
|
--without-jemalloc
|
|
)
|
|
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
multilib_src_install_all() {
|
|
einstalldocs
|
|
find "${ED}"/usr -type f -name '*.la' -delete || die
|
|
}
|