mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-15 06:29:24 +00:00
d83e25b6a5sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
103 lines
2.5 KiB
Bash
103 lines
2.5 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit linux-info meson systemd
|
|
|
|
DESCRIPTION="A small daemon to act on remote or local events"
|
|
HOMEPAGE="https://www.eventd.org/"
|
|
SRC_URI="https://www.eventd.org/download/eventd/${P}.tar.xz"
|
|
|
|
LICENSE="GPL-3+ LGPL-3+ ISC MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="debug fbcon +introspection libcanberra libnotify +notification
|
|
pulseaudio purple speech systemd test upnp webhook websocket +X zeroconf"
|
|
|
|
RESTRICT="!test? ( test )"
|
|
REQUIRED_USE="
|
|
X? ( notification )
|
|
fbcon? ( notification )
|
|
notification? ( || ( X fbcon ) )
|
|
test? ( websocket )
|
|
"
|
|
|
|
COMMON_DEPEND="
|
|
dev-libs/glib:2
|
|
sys-apps/util-linux
|
|
x11-libs/libxkbcommon
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
|
|
libcanberra? ( media-libs/libcanberra )
|
|
libnotify? ( x11-libs/gdk-pixbuf:2 )
|
|
notification? (
|
|
gnome-base/librsvg
|
|
x11-libs/cairo
|
|
x11-libs/pango
|
|
x11-libs/gdk-pixbuf:2
|
|
X? (
|
|
x11-libs/cairo[X,xcb(+)]
|
|
x11-libs/libxcb:=[xkb(+)]
|
|
x11-libs/xcb-util
|
|
x11-libs/xcb-util-wm
|
|
)
|
|
)
|
|
pulseaudio? (
|
|
media-libs/libpulse
|
|
media-libs/libsndfile
|
|
)
|
|
purple? ( net-im/pidgin )
|
|
speech? ( app-accessibility/speech-dispatcher )
|
|
systemd? ( sys-apps/systemd:= )
|
|
upnp? ( net-libs/gssdp:1.6= )
|
|
webhook? ( net-libs/libsoup:3.0 )
|
|
websocket? ( net-libs/libsoup:3.0 )
|
|
zeroconf? ( net-dns/avahi[dbus] )
|
|
"
|
|
DEPEND="
|
|
${COMMON_DEPEND}
|
|
fbcon? ( virtual/os-headers )
|
|
"
|
|
RDEPEND="
|
|
${COMMON_DEPEND}
|
|
net-libs/glib-networking[ssl]
|
|
"
|
|
BDEPEND="
|
|
app-text/docbook-xml-dtd:4.5
|
|
app-text/docbook-xsl-stylesheets
|
|
dev-libs/libxslt
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
src_configure() {
|
|
# wayland disabled due to missing dep in ::gentoo, wayland-wall
|
|
local emesonargs=(
|
|
-Dsystemduserunitdir="$(systemd_get_userunitdir)"
|
|
-Dsystemdsystemunitdir="$(systemd_get_systemunitdir)"
|
|
-Ddbussessionservicedir="${EPREFIX}/usr/share/dbus-1/services"
|
|
-Dnd-wayland=false
|
|
-Dvapi=false
|
|
$(meson_feature websocket)
|
|
$(meson_feature zeroconf dns-sd)
|
|
$(meson_feature upnp ssdp)
|
|
-Dipv6=true
|
|
$(meson_use systemd)
|
|
$(meson_use notification notification-daemon)
|
|
$(meson_use X nd-xcb)
|
|
$(meson_use fbcon nd-fbdev)
|
|
$(meson_use purple im)
|
|
$(meson_use pulseaudio sound)
|
|
$(meson_use speech tts)
|
|
$(meson_use webhook)
|
|
$(meson_use libnotify)
|
|
$(meson_use libcanberra)
|
|
$(meson_use introspection gobject-introspection)
|
|
$(meson_use debug debug-output)
|
|
)
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
EVENTD_TESTS_TMP_DIR="${T}" meson_src_test
|
|
}
|