mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-08 06:09:43 +02:00
fdf841d789
Closes: https://bugs.gentoo.org/952636 Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
59 lines
1.4 KiB
Bash
59 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{9..13} )
|
|
|
|
inherit cmake python-single-r1
|
|
|
|
DESCRIPTION="IEEE 802.15.4 ZigBee Transceiver"
|
|
HOMEPAGE="https://github.com/bastibl/gr-ieee802-15-4"
|
|
|
|
if [[ ${PV} == 9999* ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/bastibl/gr-ieee802-15-4.git"
|
|
EGIT_BRANCH="maint-3.9"
|
|
else
|
|
COMMIT="1a2999ce2778df279870f028a4ce15d94e60fbd9"
|
|
SRC_URI="https://github.com/bastibl/gr-ieee802-15-4/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/gr-ieee802-15-4-${COMMIT}"
|
|
KEYWORDS="~amd64 ~x86"
|
|
fi
|
|
|
|
LICENSE="GPL-3"
|
|
SLOT="0/${PV}"
|
|
|
|
RDEPEND="net-wireless/gnuradio:0=[${PYTHON_SINGLE_USEDEP}]
|
|
$(python_gen_cond_dep '
|
|
dev-libs/boost:=[python,${PYTHON_USEDEP}]
|
|
dev-python/pybind11[${PYTHON_USEDEP}]
|
|
')
|
|
dev-libs/gmp
|
|
dev-libs/spdlog:=
|
|
sci-libs/volk:=
|
|
${PYTHON_DEPS}"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="dev-lang/swig"
|
|
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
|
|
src_prepare() {
|
|
# fix path for doc files
|
|
sed -i "s/802_15_4 CXX/802154 CXX/" CMakeLists.txt || die
|
|
cmake_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DPYTHON_EXECUTABLE="${PYTHON}"
|
|
)
|
|
cmake_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
cmake_src_install
|
|
# Remove stray python files generated by the build system
|
|
find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
|
|
find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
|
|
python_optimize
|
|
}
|