mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-12 16:18:42 +02:00
c19c464def
This is the 2006 edition of the software. It has a bunch of useful fixes: - it fixes Modern C porting issues - it fixes LTO errors - it incorporates the glibc-2.10 patch just by upgrading! It's about time we upgrade, since it is 18 years later. Along the way we fix up the ebuild a bit: - bump to EAPI 8 - acquire an actual SRC_URI, not just the gentoo mirror - update the homepage along with the SRC_URI. The original homepage is dead, and the domain redirects to a new domain (whence comes the new distfile). It has some shortcomings too: - the distfile comes with free .svn directories, which have to be pruned. - the distfile comes without the 80mb demos To solve this, we use the old distfile (which I think only exists on Gentoo's mirror network) and gate it behind a USE=examples flag, in case anyone needs them. Closes: https://bugs.gentoo.org/862285 Closes: https://bugs.gentoo.org/884283 Signed-off-by: Eli Schwartz <eschwartz93@gmail.com> Signed-off-by: Sam James <sam@gentoo.org>
61 lines
1.1 KiB
Bash
61 lines
1.1 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit toolchain-funcs vcs-clean
|
|
|
|
DESCRIPTION="Prototype ncRNA genefinder"
|
|
HOMEPAGE="http://eddylab.org/software.html"
|
|
SRC_URI="
|
|
http://eddylab.org/software/qrna/qrna.tar.gz -> ${P}.tar.gz
|
|
examples? ( mirror://gentoo/qrna-2.0.3c.tar.bz2 )
|
|
"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="examples"
|
|
|
|
RDEPEND="
|
|
dev-lang/perl
|
|
sci-biology/hmmer:2"
|
|
DEPEND="${RDEPEND}"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${P}-ldflags.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
esvn_clean
|
|
rm -v squid*/*.a || die
|
|
}
|
|
|
|
src_configure() {
|
|
tc-export AR CC RANLIB
|
|
}
|
|
|
|
src_compile() {
|
|
local d
|
|
for d in squid squid02 src; do
|
|
emake -C ${d}
|
|
done
|
|
}
|
|
|
|
src_install() {
|
|
dobin src/{cfgbuild,eqrna,eqrna_sample,rnamat_main} scripts/*
|
|
|
|
newdoc 00README README
|
|
dodoc -r documentation/.
|
|
|
|
insinto /usr/share/${PN}/data
|
|
doins -r lib/.
|
|
if use examples; then
|
|
insinto /usr/share/${PN}/demos
|
|
doins -r "${WORKDIR}"/qrna-2.0.3c/Demos/.
|
|
fi
|
|
|
|
# Sets the path to the QRNA data files
|
|
doenvd "${FILESDIR}"/26qrna
|
|
}
|