mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-16 15:14:38 +00:00
808b7a2419Bug: https://bugs.gentoo.org/964799 Signed-off-by: Sv. Lockal <lockalsash@gmail.com> Part-of: https://github.com/gentoo/gentoo/pull/44165 Signed-off-by: Sam James <sam@gentoo.org>
64 lines
1.4 KiB
Bash
64 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
ROCM_VERSION=${PV}
|
|
|
|
inherit cmake rocm
|
|
|
|
DESCRIPTION="Generate pseudo-random and quasi-random numbers"
|
|
HOMEPAGE="https://github.com/ROCm/rocm-libraries/tree/develop/projects/rocrand"
|
|
SRC_URI="https://github.com/ROCm/${PN}/archive/rocm-${PV}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/rocRAND-rocm-${PV}"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0/$(ver_cut 1-2)"
|
|
KEYWORDS="~amd64"
|
|
IUSE="benchmark test"
|
|
REQUIRED_USE="${ROCM_REQUIRED_USE}"
|
|
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-util/hip:${SLOT}
|
|
benchmark? ( dev-cpp/benchmark )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
dev-build/rocm-cmake
|
|
test? ( dev-cpp/gtest )"
|
|
BDEPEND="dev-build/rocm-cmake
|
|
>=dev-build/cmake-3.22"
|
|
|
|
src_configure() {
|
|
rocm_use_clang
|
|
|
|
export ROCM_PATH="${EPREFIX}/usr"
|
|
|
|
local mycmakeargs=(
|
|
-DCMAKE_SKIP_RPATH=ON
|
|
-DAMDGPU_TARGETS="$(get_amdgpu_flags)"
|
|
-DBUILD_FILE_REORG_BACKWARD_COMPATIBILITY=OFF
|
|
-DROCM_SYMLINK_LIBS=OFF
|
|
-DBUILD_TEST=$(usex test ON OFF)
|
|
-DBUILD_BENCHMARK=$(usex benchmark ON OFF)
|
|
)
|
|
|
|
cmake_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
check_amdgpu
|
|
export LD_LIBRARY_PATH="${BUILD_DIR}/library"
|
|
# uses HMM to fit tests to default <512M iGPU VRAM
|
|
ROCRAND_USE_HMM="1" cmake_src_test -j1
|
|
}
|
|
|
|
src_install() {
|
|
cmake_src_install
|
|
|
|
if use benchmark; then
|
|
cd "${BUILD_DIR}"/benchmark || die
|
|
dobin benchmark_rocrand_*
|
|
fi
|
|
}
|