gentoo-ebuilds/sys-apps/bubblewrap/bubblewrap-0.11.0.ebuild
Arthur Zamarin f8ed76b201
sys-apps/bubblewrap: Stabilize 0.11.0 ppc64, #946484
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
2024-12-21 17:16:04 +00:00

59 lines
1.2 KiB
Bash

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit bash-completion-r1 linux-info meson
DESCRIPTION="Unprivileged sandboxing tool, namespaces-powered chroot-like solution"
HOMEPAGE="https://github.com/containers/bubblewrap/"
SRC_URI="https://github.com/containers/${PN}/releases/download/v${PV}/${P}.tar.xz"
LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv x86"
IUSE="selinux suid"
RDEPEND="
sys-libs/libseccomp
sys-libs/libcap
selinux? ( >=sys-libs/libselinux-2.1.9 )
"
DEPEND="${RDEPEND}"
BDEPEND="
app-text/docbook-xml-dtd:4.3
app-text/docbook-xsl-stylesheets
dev-libs/libxslt
virtual/pkgconfig
"
# tests require root privileges
RESTRICT="test"
pkg_setup() {
if [[ ${MERGE_TYPE} != buildonly ]]; then
CONFIG_CHECK="~UTS_NS ~IPC_NS ~USER_NS ~PID_NS ~NET_NS"
linux-info_pkg_setup
fi
}
src_configure() {
local emesonargs=(
-Dbash_completion=enabled
-Dbash_completion_dir="$(get_bashcompdir)"
-Dman=enabled
-Dtests=false
-Dzsh_completion=enabled
$(meson_feature selinux)
)
meson_src_configure
}
src_install() {
meson_src_install
if use suid; then
chmod u+s "${ED}"/usr/bin/bwrap
fi
}