mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-06-12 08:08:56 +02:00
6a09a84a9c
Closes: https://bugs.gentoo.org/933870 Signed-off-by: Guillermo Joandet <gjoandet@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/38095 Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
58 lines
1.1 KiB
Bash
58 lines
1.1 KiB
Bash
# Copyright 1999-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit linux-info meson
|
|
|
|
DESCRIPTION="Unprivileged sandboxing tool, namespaces-powered chroot-like solution"
|
|
HOMEPAGE="https://github.com/containers/bubblewrap/"
|
|
SRC_URI="https://github.com/containers/${PN}/releases/download/v${PV}/${P}.tar.xz"
|
|
|
|
LICENSE="LGPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
|
IUSE="selinux suid"
|
|
|
|
RDEPEND="
|
|
sys-libs/libseccomp
|
|
sys-libs/libcap
|
|
selinux? ( >=sys-libs/libselinux-2.1.9 )
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
app-text/docbook-xml-dtd:4.3
|
|
app-text/docbook-xsl-stylesheets
|
|
dev-libs/libxslt
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
# tests require root privileges
|
|
RESTRICT="test"
|
|
|
|
pkg_setup() {
|
|
if [[ ${MERGE_TYPE} != buildonly ]]; then
|
|
CONFIG_CHECK="~UTS_NS ~IPC_NS ~USER_NS ~PID_NS ~NET_NS"
|
|
linux-info_pkg_setup
|
|
fi
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
-Dbash_completion=enabled
|
|
-Dman=enabled
|
|
-Dtests=false
|
|
-Dzsh_completion=enabled
|
|
$(meson_feature selinux)
|
|
)
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
|
|
if use suid; then
|
|
chmod u+s "${ED}"/usr/bin/bwrap
|
|
fi
|
|
}
|