mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-07-21 22:53:31 +02:00
bafe53e916
Closes: https://github.com/gentoo/gentoo/pull/39133 Signed-off-by: Violet Purcell <vimproved@inventati.org> Signed-off-by: Yixun Lan <dlan@gentoo.org>
49 lines
1.1 KiB
Bash
49 lines
1.1 KiB
Bash
# Copyright 2023-2024 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{10..13} )
|
|
inherit linux-info python-single-r1 systemd
|
|
|
|
DESCRIPTION="Daemon to work around throttling issues on some Intel laptops"
|
|
HOMEPAGE="https://github.com/erpalma/throttled"
|
|
SRC_URI="https://github.com/erpalma/throttled/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
IUSE="test"
|
|
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
CONFIG_CHECK="~X86_MSR ~DEVMEM"
|
|
|
|
RDEPEND="
|
|
${PYTHON_DEPS}
|
|
$(python_gen_cond_dep '
|
|
dev-python/dbus-python[${PYTHON_USEDEP}]
|
|
dev-python/pygobject[${PYTHON_USEDEP}]
|
|
')
|
|
sys-apps/pciutils
|
|
test? ( dev-python/pytest-import-check )
|
|
"
|
|
|
|
pkg_setup() {
|
|
linux-info_pkg_setup
|
|
python-single-r1_pkg_setup
|
|
}
|
|
|
|
src_test() {
|
|
epytest -p no:python --import-check mmio.py throttled.py
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
python_newscript throttled.py throttled
|
|
python_domodule mmio.py
|
|
newinitd "${FILESDIR}/throttled.initd" throttled
|
|
systemd_dounit "${FILESDIR}/throttled.service"
|
|
insinto /etc
|
|
doins etc/throttled.conf
|
|
}
|