mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-19 00:18:26 +00:00
da5b696f97Signed-off-by: Henning Schild <henning@hennsch.de> Signed-off-by: Yixun Lan <dlan@gentoo.org>
96 lines
2.3 KiB
Bash
96 lines
2.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{10..13} )
|
|
|
|
inherit distutils-r1 optfeature systemd
|
|
|
|
MY_P=${P^}
|
|
DESCRIPTION="A simple CalDAV calendar server"
|
|
HOMEPAGE="https://radicale.org/"
|
|
SRC_URI="
|
|
https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S=${WORKDIR}/${MY_P}
|
|
|
|
LICENSE="GPL-3+"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~arm ~x86"
|
|
|
|
RDEPEND="
|
|
>=acct-user/radicale-0-r2
|
|
acct-group/radicale
|
|
dev-python/defusedxml[${PYTHON_USEDEP}]
|
|
dev-python/passlib[${PYTHON_USEDEP}]
|
|
dev-python/vobject[${PYTHON_USEDEP}]
|
|
sys-apps/util-linux
|
|
"
|
|
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/pytest[${PYTHON_USEDEP}]
|
|
dev-python/waitress[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
RDIR=/var/lib/"${PN}"
|
|
|
|
DOCS=( DOCUMENTATION.md CHANGELOG.md )
|
|
|
|
python_test() {
|
|
epytest -o addopts= radicale/tests/
|
|
}
|
|
|
|
python_install_all() {
|
|
rm README* || die
|
|
# init file
|
|
newinitd "${FILESDIR}"/radicale-r4.init.d radicale
|
|
systemd_dounit "${FILESDIR}/${PN}.service"
|
|
|
|
# directories
|
|
keepdir "${RDIR}"
|
|
fperms 0750 "${RDIR}"
|
|
fowners "${PN}:${PN}" "${RDIR}"
|
|
|
|
# config file
|
|
insinto /etc/"${PN}"
|
|
doins config
|
|
|
|
# fcgi and wsgi files
|
|
exeinto /usr/share/"${PN}"
|
|
doexe radicale.wsgi
|
|
|
|
distutils-r1_python_install_all
|
|
}
|
|
|
|
pkg_postinst() {
|
|
local _erdir="${EROOT}${RDIR}"
|
|
|
|
ewarn ""
|
|
ewarn "Since 3.5.0 the default [auth] type is \"denyall\". You need to"
|
|
ewarn "change your config if you used the deafult type so far!"
|
|
ewarn ""
|
|
einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
|
|
einfo "You will also find there an example FastCGI script."
|
|
if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
|
|
then
|
|
ewarn ""
|
|
ewarn "Unsafe file permissions detected on ${_erdir}."
|
|
ewarn "This probably comes from an earlier version of this ebuild."
|
|
ewarn "To fix run:"
|
|
ewarn "# \`chown -R ${PN}:${PN} ${_erdir}\`"
|
|
ewarn "# \`chmod 0750 ${_erdir}\`"
|
|
ewarn "# \`chmod -R o= ${_erdir}\`"
|
|
fi
|
|
|
|
optfeature "Publish changes to rabbitmq" dev-python/pika
|
|
optfeature "LDAP/LDAPS authentication" dev-python/ldap3 dev-python/python-ldap
|
|
optfeature "bcrypt password hashing" dev-python/bcrypt
|
|
optfeature "argon2 password hashing" dev-python/argon2-cffi
|
|
}
|