mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-16 23:19:31 +00:00
0ad96e879bResult of running the command: grep --include="*.ebuild" -r . -e 'KEYWORDS=.*[" ]sparc' -l | xargs ekeyword ~sparc Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
47 lines
1.3 KiB
Bash
47 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
XORG_DOC=doc
|
|
XORG_MULTILIB=yes
|
|
inherit toolchain-funcs xorg-3
|
|
|
|
# Note: please bump this with x11-misc/compose-tables
|
|
DESCRIPTION="X.Org X11 library"
|
|
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
|
|
IUSE="test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
# HACK: libX11 produces .pc files that depend on xproto.pc. When libX11
|
|
# is installed as a binpkg, DEPEND packages are not pulled in,
|
|
# but to build source packages against libX11, xorg-proto is
|
|
# needed. Until a "build-against-depend" option is available in
|
|
# ebuilds, we RDEPEND on xproto. See bug #903707 and others.
|
|
RDEPEND="
|
|
>=x11-libs/libxcb-1.11.1[${MULTILIB_USEDEP}]
|
|
x11-misc/compose-tables
|
|
x11-base/xorg-proto
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
x11-libs/xtrans
|
|
"
|
|
BDEPEND="test? ( dev-lang/perl )"
|
|
|
|
src_configure() {
|
|
local XORG_CONFIGURE_OPTIONS=(
|
|
$(use_with doc xmlto)
|
|
$(use_enable doc specs)
|
|
--enable-ipv6
|
|
--without-fop
|
|
--with-keysymdefdir="${ESYSROOT}/usr/include/X11"
|
|
CPP="$(tc-getPROG CPP cpp)"
|
|
)
|
|
xorg-3_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
xorg-3_src_install
|
|
rm -rf "${ED}"/usr/share/X11/locale || die
|
|
}
|