mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2025-12-13 13:41:05 +00:00
26703d4aa3* Rebuild on windowmaker soname update. * Filter-lto * Fix C prototype to work with GCC-15 C23 default Bug: https://bugs.gentoo.org/944013 Bug: https://bugs.gentoo.org/941640 Bug: https://bugs.gentoo.org/641740 Signed-off-by: Alfred Wingate <parona@protonmail.com> Part-of: https://github.com/gentoo/gentoo/pull/44437 Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
70 lines
1.3 KiB
Bash
70 lines
1.3 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit autotools flag-o-matic pam toolchain-funcs
|
|
|
|
DESCRIPTION="WINGs Display Manager"
|
|
HOMEPAGE="https://github.com/voins/wdm"
|
|
SRC_URI="http://voins.program.ru/${PN}/${P}.tar.bz2"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
|
|
IUSE="pam selinux truetype"
|
|
|
|
DEPEND="
|
|
virtual/libcrypt:=
|
|
x11-libs/libX11
|
|
x11-libs/libXau
|
|
x11-libs/libXdmcp
|
|
x11-libs/libXinerama
|
|
x11-libs/libXmu
|
|
x11-wm/windowmaker:=
|
|
pam? ( sys-libs/pam )
|
|
truetype? ( x11-libs/libXft )
|
|
"
|
|
RDEPEND="${DEPEND}
|
|
pam? ( >=sys-auth/pambase-20080219.1 )
|
|
"
|
|
BDEPEND="
|
|
sys-devel/gettext
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${P}-terminateServer.patch
|
|
"${FILESDIR}"/${P}-remove-fakehome.patch
|
|
"${FILESDIR}"/${P}-remove-sigsetmask.patch
|
|
"${FILESDIR}"/${P}-pkg_config.patch
|
|
"${FILESDIR}"/${P}-ar.patch
|
|
"${FILESDIR}"/${P}-prototype.patch
|
|
)
|
|
|
|
src_prepare() {
|
|
default
|
|
eautoreconf
|
|
}
|
|
src_configure() {
|
|
tc-export AR
|
|
|
|
# lto-type-mismatch
|
|
# bug #941640
|
|
filter-lto
|
|
|
|
econf \
|
|
--with-wdmdir="${EPREFIX}"/etc/X11/wdm \
|
|
$(use_enable pam) \
|
|
$(use_enable selinux)
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
|
|
rm -f "${ED}"/etc/pam.d/wdm || die
|
|
|
|
if use pam; then
|
|
pamd_mimic system-local-login wdm auth account password session
|
|
fi
|
|
}
|