mirror of
https://github.com/vim/vim
synced 2025-03-20 08:45:11 +01:00
93197fde0f
Problem: The "*.*" browsefilter pattern only matches all files on Windows (Daryl Lee) Solution: Use "*" to filter on all platforms but keep "*.*" as the label text on Windows. (Fixes #12685, Doug Kearns) The *.* browsefilter pattern used to match "All Files" on Windows is a legacy of the DOS 8.3 filename wildcard matching algorithm. For reasons of backward compatibility this still works on Windows to match all files, even those without an extension. However, this pattern only matches filenames containing a dot on other platforms. This often makes files without an extension difficult to access from the file dialog, e.g., "Makefile" On Windows it is still standard practice to use "*.*" for the filter label so ftplugins should use "All Files (*.*)" on Windows and "All Files (*)" on other platforms. This matches Vim's default browsefilter values. This commit also normalises the browsefilter conditional test to check for the Win32 and GTK GUI features and an unset b:browsefilter. closes: #12759 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
74 lines
2.1 KiB
VimL
74 lines
2.1 KiB
VimL
" Vim filetype plugin file
|
|
" Language: xhtml
|
|
"
|
|
" This runtime file is looking for a new maintainer.
|
|
"
|
|
" Former maintainer: Dan Sharp
|
|
" Last Changed: 2009 Jan 20
|
|
" 2024 Jan 14 by Vim Project (browsefilter)
|
|
|
|
if exists("b:did_ftplugin") | finish | endif
|
|
|
|
" Make sure the continuation lines below do not cause problems in
|
|
" compatibility mode.
|
|
let s:save_cpo = &cpo
|
|
set cpo-=C
|
|
|
|
" Define some defaults in case the included ftplugins don't set them.
|
|
let s:undo_ftplugin = ""
|
|
let s:browsefilter = "HTML Files (*.html, *.htm)\t*.html;*.htm\n" .
|
|
\ "XML Files (*.xml)\t*.xml\n"
|
|
if has("win32")
|
|
let s:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let s:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
let s:match_words = ""
|
|
|
|
runtime! ftplugin/xml.vim ftplugin/xml_*.vim ftplugin/xml/*.vim
|
|
unlet b:did_ftplugin
|
|
|
|
" Override our defaults if these were set by an included ftplugin.
|
|
if exists("b:undo_ftplugin")
|
|
let s:undo_ftplugin = b:undo_ftplugin
|
|
unlet b:undo_ftplugin
|
|
endif
|
|
if exists("b:browsefilter")
|
|
let s:browsefilter = b:browsefilter
|
|
unlet b:browsefilter
|
|
endif
|
|
if exists("b:match_words")
|
|
let s:match_words = b:match_words
|
|
unlet b:match_words
|
|
endif
|
|
|
|
runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
|
|
let b:did_ftplugin = 1
|
|
|
|
" Combine the new set of values with those previously included.
|
|
if exists("b:undo_ftplugin")
|
|
let s:undo_ftplugin = b:undo_ftplugin . " | " . s:undo_ftplugin
|
|
endif
|
|
if exists("b:browsefilter")
|
|
let s:browsefilter = b:browsefilter . s:browsefilter
|
|
endif
|
|
if exists("b:match_words")
|
|
let s:match_words = b:match_words . "," . s:match_words
|
|
endif
|
|
|
|
" Load the combined list of match_words for matchit.vim
|
|
if exists("loaded_matchit")
|
|
let b:match_words = s:match_words
|
|
endif
|
|
|
|
" Change the :browse e filter to primarily show tcsh-related files.
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter="XHTML files (*.xhtml, *.xhtm)\t*.xhtml;*.xhtm\n" . s:browsefilter
|
|
endif
|
|
|
|
" Undo the stuff we changed.
|
|
let b:undo_ftplugin = "unlet! b:browsefilter b:match_words | " . s:undo_ftplugin
|
|
|
|
" Restore the saved compatibility options.
|
|
let &cpo = s:save_cpo
|
|
unlet s:save_cpo
|