mirror of
https://github.com/vim/vim
synced 2025-03-15 14:27:53 +01:00
93197fde0f
Problem: The "*.*" browsefilter pattern only matches all files on Windows (Daryl Lee) Solution: Use "*" to filter on all platforms but keep "*.*" as the label text on Windows. (Fixes #12685, Doug Kearns) The *.* browsefilter pattern used to match "All Files" on Windows is a legacy of the DOS 8.3 filename wildcard matching algorithm. For reasons of backward compatibility this still works on Windows to match all files, even those without an extension. However, this pattern only matches filenames containing a dot on other platforms. This often makes files without an extension difficult to access from the file dialog, e.g., "Makefile" On Windows it is still standard practice to use "*.*" for the filter label so ftplugins should use "All Files (*.*)" on Windows and "All Files (*)" on other platforms. This matches Vim's default browsefilter values. This commit also normalises the browsefilter conditional test to check for the Win32 and GTK GUI features and an unset b:browsefilter. closes: #12759 Signed-off-by: Doug Kearns <dougkearns@gmail.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
76 lines
2.4 KiB
VimL
76 lines
2.4 KiB
VimL
" Vim filetype plugin file
|
|
" Language: Perl POD format
|
|
" Maintainer: vim-perl <vim-perl@googlegroups.com>
|
|
" Author: Doug Kearns <dougkearns@gmail.com>
|
|
" Homepage: https://github.com/vim-perl/vim-perl
|
|
" Bugs/requests: https://github.com/vim-perl/vim-perl/issues
|
|
" License: Vim License (see :help license)
|
|
" Last Change: 2023 Jul 05
|
|
" Last Change: 2021 Oct 19
|
|
" 2024 Jan 14 by Vim Project (browsefilter)
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:save_cpo = &cpo
|
|
set cpo-=C
|
|
|
|
setlocal comments=fb:=for\ comment
|
|
setlocal commentstring==for\ comment\ %s
|
|
|
|
let b:undo_ftplugin = "setl com< cms<"
|
|
|
|
if exists("loaded_matchit") && !exists("b:match_words")
|
|
let b:match_words =
|
|
\ '^=pod\>:^=cut\>,' .
|
|
\ '^=begin\s\+\(\S\+\):^=end\s\+\1,' .
|
|
\ '^=over\>:^=item\>:^=back\>,' .
|
|
\ '[IBCLEFSXZ]<<\%(\s\+\|$\)\@=:\%(\s\+\|^\)\@<=>>,' .
|
|
\ '[IBCLEFSXZ]<:>'
|
|
let b:undo_ftplugin .= " | unlet! b:match_words"
|
|
endif
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "POD Source Files (*.pod)\t*.pod\n" .
|
|
\ "Perl Source Files (*.pl)\t*.pl\n" .
|
|
\ "Perl Modules (*.pm)\t*.pm\n"
|
|
if has("win32")
|
|
let b:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin .= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
function s:jumpToSection(direction)
|
|
let flags = a:direction == "backward" ? "bsWz" : "sWz"
|
|
if has("syntax_items")
|
|
let skip = "synIDattr(synID(line('.'), col('.'), 1), 'name') !~# '\\<podCommand\\>'"
|
|
else
|
|
let skip = ""
|
|
endif
|
|
for i in range(v:count1)
|
|
call search('^=\a', flags, 0, 0, skip)
|
|
endfor
|
|
endfunction
|
|
|
|
if !exists("no_plugin_maps") && !exists("no_pod_maps")
|
|
for s:mode in ["n", "o", "x"]
|
|
for s:lhs in ["]]", "]["]
|
|
execute s:mode . "noremap <silent> <buffer> " . s:lhs . " <Cmd>call <SID>jumpToSection('forward')<CR>"
|
|
let b:undo_ftplugin .= " | silent! execute '" . s:mode . "unmap <buffer> " . s:lhs . "'"
|
|
endfor
|
|
for s:lhs in ["[[", "[]"]
|
|
execute s:mode . "noremap <silent> <buffer> " . s:lhs . " <Cmd>call <SID>jumpToSection('backward')<CR>"
|
|
let b:undo_ftplugin .= " | silent! execute '" . s:mode . "unmap <buffer> " . s:lhs . "'"
|
|
endfor
|
|
endfor
|
|
unlet s:mode s:lhs
|
|
endif
|
|
|
|
let &cpo = s:save_cpo
|
|
unlet s:save_cpo
|
|
|
|
" vim: set expandtab:
|