mirror of
https://github.com/vim/vim
synced 2025-03-15 14:27:53 +01:00
150b5078ac
closes: #15618 Signed-off-by: Gregory Anders <greg@gpanders.com> Signed-off-by: Christian Brabandt <cb@256bit.org>
40 lines
1.1 KiB
VimL
40 lines
1.1 KiB
VimL
" Language: HCL
|
|
" Maintainer: Gregory Anders
|
|
" Last Change: 2024-09-03
|
|
" Based on: https://github.com/hashivim/vim-terraform
|
|
|
|
function! hcl#indentexpr(lnum)
|
|
" Beginning of the file should have no indent
|
|
if a:lnum == 0
|
|
return 0
|
|
endif
|
|
|
|
" Usual case is to continue at the same indent as the previous non-blank line.
|
|
let prevlnum = prevnonblank(a:lnum-1)
|
|
let thisindent = indent(prevlnum)
|
|
|
|
" If that previous line is a non-comment ending in [ { (, increase the
|
|
" indent level.
|
|
let prevline = getline(prevlnum)
|
|
if prevline !~# '^\s*\(#\|//\)' && prevline =~# '[\[{\(]\s*$'
|
|
let thisindent += &shiftwidth
|
|
endif
|
|
|
|
" If the current line ends a block, decrease the indent level.
|
|
let thisline = getline(a:lnum)
|
|
if thisline =~# '^\s*[\)}\]]'
|
|
let thisindent -= &shiftwidth
|
|
endif
|
|
|
|
" If the previous line starts a block comment /*, increase by one
|
|
if prevline =~# '/\*'
|
|
let thisindent += 1
|
|
endif
|
|
|
|
" If the previous line ends a block comment */, decrease by one
|
|
if prevline =~# '\*/'
|
|
let thisindent -= 1
|
|
endif
|
|
|
|
return thisindent
|
|
endfunction
|